Calling object methods

[AndyS19]

I'm writing code to manage print jobs.  The on-line searches I did showed different ways of calling a print job method.
I see these ways of calling print job methods:

$oPrintjob.Delete_   (Method name followed by underline)
$oPrintJob.Resume()  (Method name followed by open/closed parens)
$oPrintJob.Status    (Method name followed by nothing at all)

I don't understand syntax where the method name is followed by an underline.

 

When is it correct to use the method name followed by an underline vs the open/closed parens vs nothing at all?

[computergroove]

It appears that .Delete_ is just how it's called. If you want to delete a printer then you use .Delete_.

http://blogs.technet.com/b/heyscriptingguy/archive/2007/11/02/hey-scripting-guy-how-can-i-remove-all-the-network-printers-on-a-computer.aspx

[water]

In AutoIt the preferred method to call methods is with parens. So it is easier to distinguish them from properties. Methods can have parameters so parens are needed.

$oPrintjob.Delete_()
$oPrintJob.Resume()
$oPrintJob.Status() ; Is this really a method?

 

[AndyS19]

OK, but the .Delete() doesn't work

Here's a test script that shows that only the .Delete_ works; not .Delete() or just .Delete

expandcollapse popup

#AutoIt3Wrapper_au3check_parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GUIConstantsEx.au3>
#include <GuiButton.au3>
#include <WindowsConstants.au3>

Opt("MustDeclareVars", 1)

Global $iMemo

Global $sPrinterName = "Brother PT-2430PC"

_Main()

Func _Main()
    Local $iPrintTestPagebtn, $iShowAllJobs
    Local $iDelete1JobMu, $iDelete1JobMp, $iDelete1JobMn

    GUICreate("Methods", 500, 400)
    $iMemo = GUICtrlCreateEdit("", 10, 10, 475, 320, $WS_VSCROLL)
    GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
    $iPrintTestPagebtn = GUICtrlCreateButton("Print Test Page", 10, 340, 100, 25)
    $iShowAllJobs = GUICtrlCreateButton("Show all Jobs", 110, 340, 100, 25)

    $iDelete1JobMu = GUICtrlCreateButton("Delete Using underline", 10, 367, 125, 25)
    $iDelete1JobMp = GUICtrlCreateButton("Delete 1 Using parens", 135, 367, 125, 25)
    $iDelete1JobMn = GUICtrlCreateButton("Delete 1 Using nothing", 260, 367, 125, 25)

    GUISetState()

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                ExitLoop
            Case $iPrintTestPagebtn
                printTestPage($sPrinterName)
            Case $iShowAllJobs
                showAllPrintJobs($sPrinterName)
            Case $iDelete1JobMu
                delete1PrintJob($sPrinterName, "underline")
            Case $iDelete1JobMp
                delete1PrintJob($sPrinterName, "parens")
            Case $iDelete1JobMn
                delete1PrintJob($sPrinterName, "nothing")
        EndSwitch
    WEnd

    Exit
EndFunc   ;==>_Main

Func delete1PrintJob($sPrinterName, $sMethod)
    Local $wbemFlags, $oWMIService, $oPrintJobs, $oPrintJob, $thisprintername
    MemoWrite("")

    $oWMIService = ObjGet("winmgmts:\\localhost\root\CIMV2")
    If (Not IsObj($oWMIService)) Then Return
    $wbemFlags = BitOR(0x20, 0x10) ; $wbemFlagReturnImmediately and wbemFlagForwardOnly
    $oPrintJobs = $oWMIService.ExecQuery("SELECT * FROM Win32_PrintJob", "WQL", $wbemFlags)

    For $oPrintJob In $oPrintJobs
        $thisprintername = StringSplit($oPrintJob.Name, ",", 2)[0]
        If (StringCompare($thisprintername, $sPrinterName) == 0) Then

            Switch ($sMethod)
                Case "underline"
                    $oPrintJob.Delete_
                Case "parens"
                    $oPrintJob.Delete()
                Case "nothing"
                    $oPrintJob.Delete
            EndSwitch

            MemoWrite("+++: Deleted: " & $oPrintJob.Document & " " & $oPrintJob.TimeSubmitted & @CRLF)
            ExitLoop
        EndIf
    Next
EndFunc   ;==>delete1PrintJob

Func showAllPrintJobs($sPrinterName)
    Local $wbemFlags, $oWMIService, $oPrintJobs, $oPrintJob, $cnt, $thisprintername
    MemoWrite("")

    $oWMIService = ObjGet("winmgmts:\\localhost\root\CIMV2")
    If (Not IsObj($oWMIService)) Then Return

    $cnt = 1
    $wbemFlags = BitOR(0x20, 0x10) ; $wbemFlagReturnImmediately and wbemFlagForwardOnly
    $oPrintJobs = $oWMIService.ExecQuery("SELECT * FROM Win32_PrintJob", "WQL", $wbemFlags)
    For $oPrintJob In $oPrintJobs
        $thisprintername = StringSplit($oPrintJob.Name, ",", 2)[0]
        If (StringCompare($thisprintername, $sPrinterName) == 0) Then
            MemoWrite("+++: PrintJob #" & $cnt & ": " & $oPrintJob.Document & " " & $oPrintJob.TimeSubmitted)
            $cnt += 1
        EndIf
    Next
EndFunc   ;==>showAllPrintJobs

Func printTestPage($sPrinterName)
    Local $params, $str
    MemoWrite("")

    $params = "/k " ; /k = Print Test Page
    $str = $params & " /n " & '"' & $sPrinterName & '"'

    DllCall("printui.dll", "none", "PrintUIEntryW", _
            "hwnd", 0, _
            "ptr", 0, _
            "wstr", $str, _
            "int", @SW_HIDE)

    MemoWrite("+++: Printing Test page" & @CRLF)
EndFunc   ;==>printTestPage

Func MemoWrite($sMessage)
    GUICtrlSetData($iMemo, StringStripWS($sMessage, 3) & @CRLF, 1)
EndFunc   ;==>MemoWrite

 

[mLipok]

$oPrintJob.Status() ; Is this really a method?

not, this is property:

https://msdn.microsoft.com/en-us/library/aa394363(v=vs.85).aspx

 

Edit:
so this should be used like this:

Local $sPrintJob_Status = $oPrintJob.Status

 

Edited September 26, 2015 by mLipok

[water]

OK, but the .Delete() doesn't work

I didn't say it should be .Delete(). I just said that every method should have parens when being used in AutoIt.
So it should be .Delete_().

[AndyS19]

Oh, I see.  Do you know where the Delete_ (with the underline) is documented.  I've searched MDN and other sites, but I don't see anything.

 

[JohnOne]

Might be a one of a kind method to distinguish deleting from any other method.

[AndyS19]

OK, thanks