Input Left Right Buttons

[Ascer 32]

Hello,

I would like to ask if there is an GUI function that allow create control like this?

[Nine 1,501]

You could use something like this :

#include <GUIConstants.au3>
#include <Constants.au3>

GUICreate("Example", 300, 100)
Local $idLeft = GUICtrlCreateLabel("<", 10, 10, 20, 20, $SS_CENTER+$SS_SUNKEN)
GUICtrlCreateLabel("Sample Item 1", 30, 10, 200, 20, $SS_CENTER+$SS_SUNKEN)
Local $idRight = GUICtrlCreateLabel(">", 230, 10, 20, 20, $SS_CENTER+$SS_SUNKEN)

GUISetState()

While True
  Switch GUIGetMsg()
    Case $GUI_EVENT_CLOSE
      ExitLoop
    Case $idLeft
      ConsoleWrite("Left was pressed" & @CRLF)
    Case $idRight
      ConsoleWrite("Right was pressed" & @CRLF)
  EndSwitch
WEnd

 

[Ascer 32]

@Nine

Thanks for respond but is not what I looking for. You just used sunken labels while maybe there is way to create example comobox or listbox with such as buttons included.

 

[Nine 1,501]

Not sure what you are looking for in fact...When you find out, just tell us.

[mLipok 1,303]

Do you mean something like this:
 

expandcollapse popup

#include <Array.au3>
#include <Constants.au3>
#include <GUIConstants.au3>
#include <GuiComboBox.au3>

_Example()

Func _Example()
    GUICreate("Example", 300, 100)
    Local $idLeft = GUICtrlCreateLabel("<", 10, 10, 20, 20, $SS_CENTER + $SS_SUNKEN)
    Local $idComboBox = GUICtrlCreateCombo("", 30, 10, 200, 20)
    ; Add additional items to the combobox.
    GUICtrlSetData($idComboBox, "Item 1|Item 2|Item 3", "Item 1")
    Local $idRight = GUICtrlCreateLabel(">", 230, 10, 20, 20, $SS_CENTER + $SS_SUNKEN)

    GUISetState()
    Local $i_Index = 0
    While True
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                ExitLoop
            Case $idLeft
                $i_Index -= 1
                _Select($idComboBox, $i_Index)
                ConsoleWrite("Left was pressed" & @CRLF)
            Case $idRight
                $i_Index += 1
                _Select($idComboBox, $i_Index)
                ConsoleWrite("Right was pressed" & @CRLF)
        EndSwitch
    WEnd
EndFunc   ;==>_Example

Func _Select($idComboBox, ByRef $i_Index)
    Local $a_COMBO_List = _GUICtrlComboBox_GetListArray($idComboBox)
    _ArrayDelete($a_COMBO_List, 0)
    If $i_Index < 0 Then $i_Index = UBound($a_COMBO_List) - 1
    If $i_Index > UBound($a_COMBO_List) - 1 Then $i_Index = 0

    _GUICtrlComboBox_SetCurSel($idComboBox, $i_Index)

EndFunc   ;==>_Select

 

?

Edited August 2, 2021 by mLipok

[Nine 1,501]

@mLipok I see what you mean.  Your CB is pretty sharp this morning...

#include <GUIConstants.au3>
#include <Constants.au3>

Local $aList = ["Sample Item 1", "Sample Item 2", "Sample Item 3", "Sample Item 4", "Sample Item 5", "Sample Item 6"]

GUICreate("Example", 300, 100)
Local $idLeft = GUICtrlCreateLabel("<", 10, 10, 20, 20, $SS_CENTER+$SS_SUNKEN)
Local $idLabel = GUICtrlCreateLabel($aList[0], 30, 10, 200, 20, $SS_CENTER+$SS_SUNKEN)
Local $idRight = GUICtrlCreateLabel(">", 230, 10, 20, 20, $SS_CENTER+$SS_SUNKEN)
Local $iShow = 0

GUISetState()

While True
  Switch GUIGetMsg()
    Case $GUI_EVENT_CLOSE
      ExitLoop
    Case $idLeft
      $iShow = Mod(UBound($aList) + $iShow - 1, UBound($aList))
      GUICtrlSetData($idLabel, $aList[$iShow])
    Case $idRight
      $iShow = Mod($iShow + 1, UBound($aList))
      GUICtrlSetData($idLabel, $aList[$iShow])
  EndSwitch
WEnd

 

[mLipok 1,303]

2 minutes ago, Nine said:

Your CB is pretty sharp this morning...

what mean CB abbreviation ?

[Nine 1,501]

Crystal Ball 

[mLipok 1,303]

2 minutes ago, Nine said:

Crystal Ball 

[Ascer 32]

Almost there! So there is no single control to do this? I need to use x3 ones?

[Nine 1,501]

Yes.  To know what direction you are going.  You could wrap it into a kind of UDF and hide the different parts. But unless you need to perform a lot of those controls, I suggest you use the basic approach.

Edited August 2, 2021 by Nine

[mLipok 1,303]

On 8/2/2021 at 3:10 PM, Ascer said:

Almost there! So there is no single control to do this? I need to use x3 ones?

Do you mean that you are looking for similar solution to GUICtrlCreateUpdown() function but related to ComboBox instead Input ?