Help - Autoit translator

[gononono64]

Hey,

So I'm trying to create a translation script to translate text from english to spanish. It seems my program crashes if i have more than 1 child in the html.(i will highlight it via comment) I am also occasionally crashing after my 5 second, while busy, loop. Any help or insight would be greatly appreciated.

 

expandcollapse popup

$langFrom = "en"
$langTo = "es"
While 1
    Sleep(250)
    Translate()
Wend



Func Translate()
    $ie = ObjCreate("InternetExplorer.Application")
    $ie.visible = True
    $toTrans = InputBox("Translate", "Enter text to translate [" & $langTo & "]")
    $ie.Navigate("https://translate.google.ca/?ie=UTF-8&hl=" & $langFrom & "&client=tw-ob#auto/" & $langTo & "/" & $toTrans)
    
    $result = ""
    
    While($ie.busy)
    Sleep(5000)
    WEnd ;occasionally crashing here (unsure cause)
    
    While($result = "")
        $result = $ie.document.getElementById("result_box").innerHTML
        sleep(250)
    WEnd
    
    $children = $ie.document.getElementById("result_box").childNodes ;suspect i did something wrong here
    
    $result = ""
    
    for $child in $children
        $result = $result & $child.innerHTML & " " ;crashing here
    Next
    
    ;cleanup
    $result = StringReplace($result,"  "," ")
    $result = StringReplace($result," ."," ")
    
    $ie.quit()
    MsgBox(0,"Translated", $result)
    
    EndFunc

 

[water]

When it crashes do you get any error messages?
Do you run it compiled or from SciTE?

[Danyfirex]

I wrote this using IE UDF.

#include <IE.au3>


MsgBox(0,"",_GoogleTraslate("Hello World. I love AutoIt"))

Func _GoogleTraslate($sTexttoTraslate, $sFrom = "en", $sTo = "es")
    Local $sResult = ""
    Local $sURL = "http://translate.google.com/#" & $sFrom & "/" & $sTo & "/" & $sTexttoTraslate
    Local $oIE = _IECreate($sURL,Default,False)
    _IELoadWait($oIE)
    Local $oResultBox = _IEGetObjById($oIE, "result_box")

    If IsObj($oResultBox) Then
        $sResult = $oResultBox.innertext
    EndIf
    _IEQuit($oIE)
    Return $sResult
EndFunc   ;==>_GoogleTraslate

Saludos

[mikell]

For a translation tool you could use a translation api (google or another one)
This one currently still works 

$mytext = "So I'm trying to create a translation script to translate text from english to spanish. " & @crlf & "It seems my program crashes..."
$from = "en"
$to = "es"
$url = "https://translate.googleapis.com/translate_a/single?client=gtx"
$url &= "&sl=" & $from & "&tl=" & $to & "&dt=t&q=" & $mytext

$oHTTP = ObjCreate("Microsoft.XMLHTTP")
$oHTTP.Open("POST", $url, False)
$oHTTP.Send()
$sData = $oHTTP.ResponseText
$sData = StringRegExpReplace($sData, '.*?\["(.*?)(?<!\\)"[^\[]*', "$1" & @crlf)
Msgbox(0,"", $sData)

 

Edited December 23, 2015 by mikell
typo

[mLipok]

I think this is realted to this track ticket:

https://www.autoitscript.com/trac/autoit/ticket/3167

So you should probably try this:

Local $oDocument = $ie.document
Local $oTemp = Null
While 1
    $oTemp = $oDocument.getElementById("result_box")
    $result = $oTemp.innerHtml
    if not @error Then ExitLoop
    sleep(250)
Wend

instead of this:

While($result = "")
        $result = $ie.document.getElementById("result_box").innerHTML
        sleep(250)
    WEnd

 

[gononono64]

Thank you @mikell this works well :D. simpler code too

Edited December 27, 2015 by gononono64