Ignore "Variable must be of type "Object"" Errors

[runinfromjason]

Hello AutoIT gang,

I am in desperate need of help. We just upgraded AutoIT, however it seems the old one let these things slide, and I need to adjust my script. This script is massive (5000 lines) and the write took several months, so for sake of argument, let's just say I want to completely ignore any unfound object errors, just as the last version did, or maybe catch the specific ones and allow the script to continue. I can use other users' information to catch the errors, but getting the script to continue has been quite the challenge, I can't even put in an IF statement with the error, because the instant it can't find the object, the whole script cancels. The issue is, this script needs to call on several objects and see which responds to know which version of SAP it is working with, as SAP updates their object names often, so I've been calling a few different possible objects and getting their returns.

For example, my script will fail at this line.. I can put an IF statement before it, after, whatever, I cannot seem to get past this error.

$sap_session.findById("usr/tblSAPLBD41TCTRL_V_TBDLS/txtV_TBDLS-LOGSYS[0,17]").caretPosition = 7

 

A couple of the errors I'm getting are either - "Variable must be of type "Object" or "The requested action with this object has failed" and using another user's function was able to get the description "The control could not be found by id.".

 

Please let me know.

Edited April 6, 2021 by runinfromjason

[Davidowicza]

Wouldn't it just be easier to just roll back your version of AutoIT if you don't want fix your script errors?

[Marc]

Global $oMyError = ObjEvent("AutoIt.Error", "_ADDoError") ; error handler einrichten

Func _ADDoError() ; Custom Error Handler
    Local $HexNumber = Hex($oMyError.number, 8)
    ConsoleWrite($HexNumer & @crlf)
    Return
EndFunc   ;==>_ADDoError

this should do the job. It's something like "on error continue" 🤪

[Gianni]

you could also try wrapping the whole statement inside an Execute () by passing it as a string; something like this:

Execute('$sap_session.findById("usr/tblSAPLBD41TCTRL_V_TBDLS/txtV_TBDLS-LOGSYS[0,17]").caretPosition = 7')

and checking @error if you need to know if the command you passed was successful or if there were any problems. In this way the script should not stop and continue without crashing even in the case of "Variable must be of type" Object "or" The requested action with this object has failed "...

See here for the source of this technique.

Edited April 6, 2021 by Chimp

[Nine]

Like @Marc said.

But if you want a streamlined version, but being able to detect the error use this :

Global $oMyError = ObjEvent("AutoIt.Error", _ErrorHandler)

$obj = ObjCreate("Scripting.Dictionary")
$obj.error()
If @error Then ConsoleWrite ("error found " & Hex(@error) & @CRLF)

Func _ErrorHandler()
EndFunc

 

[runinfromjason]

Thanks for the replies, all great ideas. The execute suggestion might actually work, I'm not sure if I can use variables in there, but I'll definitely look more into that. 

These functions to catch the errors work great for the "The requested action with this object has failed" errors, however, they do not seem to work on the "Variable must be of type Object" errors. Does anyone know why that might be? Shouldn't these catch all object errors?

 

Let's use this one for example..

Global $oMyError = ObjEvent("AutoIt.Error", "_ADDoError") ; error handler einrichten

Func _ADDoError() ; Custom Error Handler
    Local $HexNumber = Hex($oMyError.number, 8)
    ConsoleWrite($HexNumer & @crlf)
    Return
EndFunc   ;==>_ADDoError

It allows the script to continue once it hits the "The requested action with this object has failed" error, however, later the script still fails, now ONLY at the particular error "Variable must be of type "Object".

[water]

36 minutes ago, runinfromjason said:

however, they do not seem to work on the "Variable must be of type Object" errors. Does anyone know why that might be? Shouldn't these catch all object errors?

This errors happen when you ignore a previous COM error.
If you try to create an object and it fails you get a COM error. if you ignore this COM error the next statement trying to access the created object (in fact it isn't an object, the variable is undefined) will fail with the mentioned eror message.

Only solution:
The COM error handler needs to decide it the error can be safely ignored or if an error handling action (display an error message, exit the script ...) is needed.

[mLipok]

2 hours ago, runinfromjason said:

$sap_session.findById("usr/tblSAPLBD41TCTRL_V_TBDLS/txtV_TBDLS-LOGSYS[0,17]").caretPosition = 7

It look's like you've been hit by this bug:

https://www.autoitscript.com/trac/autoit/ticket/3167

To work around the problem in your code, your code should look's like this:

Local $oTemp = $sap_session.findById("usr/tblSAPLBD41TCTRL_V_TBDLS/txtV_TBDLS-LOGSYS[0,17]")
$oTemp.caretPosition = 7

instead:

$sap_session.findById("usr/tblSAPLBD41TCTRL_V_TBDLS/txtV_TBDLS-LOGSYS[0,17]").caretPosition = 7

Edited April 6, 2021 by mLipok

[runinfromjason]

Quote

The COM error handler needs to decide it the error can be safely ignored or if an error handling action (display an error message, exit the script ...) is needed.

This all makes sense, but is there a way to control how it decides what to do with these errors? Using the example above, which I've tried, it is telling the system how to handle the error in the If @error statement.

Global $oMyError = ObjEvent("AutoIt.Error", _ErrorHandler)

$obj = ObjCreate("Scripting.Dictionary")
$obj.error()
If @error Then ConsoleWrite ("error found " & Hex(@error) & @CRLF)

Func _ErrorHandler()
EndFunc

 

[mLipok]

.....
Global $oMyError = ObjEvent("AutoIt.Error", _COM_ErrFunc)
.....
_Example()
Func _Example()
    .........
    Local $oTemp = $sap_session.findById("usr/tblSAPLBD41TCTRL_V_TBDLS/txtV_TBDLS-LOGSYS[0,17]")
    If @error Then ............
    $oTemp.caretPosition = 7
    If @error Then ............
    .........
EndFunc
.....
; User's COM error function. Will be called if COM error occurs
Func _COM_ErrFunc(ByRef $oError)
        ; Do anything here.
        ConsoleWrite(@ScriptName & " (" & $oError.scriptline & ") : ==> COM Error intercepted !" & @CRLF & _
                        @TAB & "err.number is: " & @TAB & @TAB & "0x" & Hex($oError.number) & @CRLF & _
                        @TAB & "err.windescription:" & @TAB & $oError.windescription & @CRLF & _
                        @TAB & "err.description is: " & @TAB & $oError.description & @CRLF & _
                        @TAB & "err.source is: " & @TAB & @TAB & $oError.source & @CRLF & _
                        @TAB & "err.helpfile is: " & @TAB & $oError.helpfile & @CRLF & _
                        @TAB & "err.helpcontext is: " & @TAB & $oError.helpcontext & @CRLF & _
                        @TAB & "err.lastdllerror is: " & @TAB & $oError.lastdllerror & @CRLF & _
                        @TAB & "err.scriptline is: " & @TAB & $oError.scriptline & @CRLF & _
                        @TAB & "err.retcode is: " & @TAB & "0x" & Hex($oError.retcode) & @CRLF & @CRLF)
EndFunc   ;==>_ErrFunc
.....

 

Edited April 6, 2021 by mLipok

[water]

@error is set to the COM error code (HRESULT) returned by the called function.
Your example returns 0x80020006 - This stands for "DISP_E_UNKNOWNNAME (Unknown name)" and can be found her:
https://docs.microsoft.com/en-us/openspecs/windows_protocols/ms-erref/705fb797-2175-4a90-b5a3-3918024b10b8

Example:

Global $oMyError = ObjEvent("AutoIt.Error", _ErrorHandler)

$obj = ObjCreate("Scripting.Dictionary")
$obj.error()
If @error = 0x80020006 Then ConsoleWrite("Error - Name not found!" & @CRLF)

Func _ErrorHandler()
EndFunc   ;==>_ErrorHandler

 

[runinfromjason]

On 4/6/2021 at 12:23 PM, mLipok said:

It look's like you've been hit by this bug:

https://www.autoitscript.com/trac/autoit/ticket/3167

To work around the problem in your code, your code should look's like this:

Local $oTemp = $sap_session.findById("usr/tblSAPLBD41TCTRL_V_TBDLS/txtV_TBDLS-LOGSYS[0,17]")
$oTemp.caretPosition = 7

instead:

$sap_session.findById("usr/tblSAPLBD41TCTRL_V_TBDLS/txtV_TBDLS-LOGSYS[0,17]").caretPosition = 7

For anyone wondering, I decided to go this route. It works, it's easy to implement and prevents the errors, exactly where I need them prevented with only a few additional lines of code.

I'd like to thank everyone else for their inputs, it gave me a much better understanding. So far, so good, I'll check back if anything else comes up.

Also, noticed, AutoIT no longer supports "" as output value for a variable. Took me 12 hours to figure out that's also what was wrong, adding to the confusion. I had to change them all to NULL!!

 

Thanks again! Ya'll smart.