OOP-like approach in AutoIt

guinness · July 9, 2015

I posted this the other day, but thought I would post in a separate topic instead.

#include <MsgBoxConstants.au3>

; ---- Start of Person Class

; Stored in the 'object' to verify it's our 'object' and not some random array
Global Const $PERSON_GUID = '4197B285-6AB1-489B-8585-08C852E33F3D'

; Friendly names for 0, 1, 2 and 3
Global Enum $PERSON_AGE, $PERSON_NAME, $PERSON_ID, $PERSON_MAX

; Constructor
Func Person($sName, $iAge)
    Local $hPerson[$PERSON_MAX]

    ; Set the GUID, so as the verification will work
    $hPerson[$PERSON_ID] = $PERSON_GUID

    Person_SetAge($hPerson, $iAge)
    Person_SetName($hPerson, $sName)

    ; Return the Person 'object'
    Return $hPerson
EndFunc   ;==>Person

; Getter for the age property
Func Person_GetAge(ByRef $hPerson)
    Return _Person_IsObject($hPerson) ? $hPerson[$PERSON_AGE] : Null
EndFunc   ;==>Person_GetAge

; Setter for the age property
Func Person_SetAge(ByRef $hPerson, $iAge)
    ; If not a valid 'object' or integer then return
    If Not _Person_IsObject($hPerson) Or Not IsInt($iAge) Then Return

    ; Set the age
    $hPerson[$PERSON_AGE] = $iAge
EndFunc   ;==>Person_SetAge

; Getter for the name property
Func Person_GetName(ByRef $hPerson)
    Return _Person_IsObject($hPerson) ? $hPerson[$PERSON_NAME] : Null
EndFunc   ;==>Person_GetName

; Setter for the name property
Func Person_SetName(ByRef $hPerson, $sName)
    ; If not a valid 'object' then return
    If Not _Person_IsObject($hPerson) Then Return

    ; Set the name
    $hPerson[$PERSON_NAME] = $sName
EndFunc   ;==>Person_SetName

; ToString() for the 'object'
Func Person_ToString(ByRef $hPerson)
    Return _Person_IsObject($hPerson) ? StringFormat('Name: %s, Age: %i', $hPerson[$PERSON_NAME], $hPerson[$PERSON_AGE]) : Null
EndFunc   ;==>Person_ToString

; Check if it's a valid 'object' and not some random array. "NTERNAL ONLY!
Func _Person_IsObject(ByRef $hPerson)
    Return UBound($hPerson) = $PERSON_MAX And $hPerson[$PERSON_ID] == $PERSON_GUID
EndFunc   ;==>_Person_IsObject

; ---- End of Person Class

Example()

Func Example()
    ; Store the Person 'object', which is just a glorified array
    Local $hP1 = Person('John', 30)

    ; Display the 'object'
    MsgBox($MB_SYSTEMMODAL, 'Person 1', Person_ToString($hP1))

    ; Create a new person

    ; Store the Person 'object', which is just a glorified array
    Local $hP2 = Person('James', 36)

    ; Display the 'object'
    MsgBox($MB_SYSTEMMODAL, 'Person 2', Person_ToString($hP2))

    ; Set the age for Person 2
    Person_SetAge($hP2, 45)

    ; Display the 'object'
    MsgBox($MB_SYSTEMMODAL, 'Person 2 - Revised', Person_ToString($hP2))
EndFunc   ;==>Example

Jefrey · July 10, 2015

I did the same on my JSONgen lol

Although using AutoItObject classes is a nice deal, creating classes is not so intuitive (I ever did it). Of course I don't blame AutoItObjects for it, even because they were limited to what AutoIt supports. I wouldn't blame AutoIt language developers too, since it was originally made just as a replacement for Microsoft ScriptIt, nothing more than a tool to automate tasks, and not creating fully-functional softwares. But AutoIt is, today, much more than what it was once. Although there are many things I dislike (like the arrays approach), I've adopted AutoIt as my main work language due to its productivity (let's just say that what I can do with 1 month in Java or C, I can do in 1 week or less in AutoIt...). I hope the AU3 coders can see soon more improvements in the languages. For starting, a native OOP support would be nice

guinness · July 10, 2015

I have been coding like this for a couple of years. So when I saw your Json script, I was pleasantly surprised.

Jefrey · July 10, 2015

What should we call this as? "Array-oriented programming"? lol

Despite the jokes, I really think it could be considered some kind of "standard". At least until we have native AutoIt OOP support...

guinness · July 10, 2015

AutoIt is based on BASIC, so it's out of scope for Jon to make it OOP.

How about AAOP - AutoIt Array Oriented Programming? By the way did you come up with the idea on your own or see a post by me or Valik?

jaberwacky · July 10, 2015

One of FreeBasic's paradigms is object orientation.

guinness · July 10, 2015

On 7/10/2015 at 1:21 PM, jaberwacky said:
One of FreeBasic's paradigms is object orientation.

I am talking about the procedural era

JohnOne · July 10, 2015

I've tried, but can't see how it could be considered OOP-Like in any shape or form.

Straight forward procedural scripting with a lot of ByRef would be more accurate for me.

Edited July 10, 2015 by JohnOne
Typo, see post below

guinness · July 10, 2015

Can or can't?

It's about the approach of encapsulating data with methods, not the execution.

Jefrey · July 10, 2015

On 7/10/2015 at 1:18 PM, guinness said:
AutoIt is based on BASIC, so it's out of scope for Jon to make it OOP.

Well, that's not so good to know it

Quote
How about AAOP - AutoIt Array Oriented Programming? By the way did you come up with the idea on your own or see a post by me or Valik?

Truly, I would write that using AutoItObject, but I thought that putting an additional DLL just for generating JSONs would sound strange. So I started coding it so on my own...

guinness · July 10, 2015

On 7/10/2015 at 1:34 PM, Jefrey said:

Truly, I would write that using AutoItObject, but I thought that putting an additional DLL just for generating JSONs would sound strange. So I started coding it so on my own...

Cool

mLipok · July 10, 2015

For several years I develop my skills intensively.
Since I took a lot of programming style of @guinness (by the way of working together on a project),.

You can find this ie. in my PDFCreator.au3

Reveal hidden contents

#Region PDFCreator.au3 - Functions CONFIG

Func _PDFCreator_Config_GetCurrent()
    __PDFCreator_ObjCreate()
    If @error Then
        Return SetError(@error)
    Else
        Local $aCONFIG[$g__ePDFCreator_CONFIG_COUNTER]
        With $g__oPDFCreator
            $aCONFIG[$g__ePDFCreator_CONFIG_Visible] = .cVisible
            $aCONFIG[$g__ePDFCreator_CONFIG_DefaultPrinter] = .cDefaultprinter
            $aCONFIG[$g__ePDFCreator_CONFIG_PrinterStop] = .cPrinterStop
            $aCONFIG[$g__ePDFCreator_CONFIG_UseAutoSave] = .cOption("UseAutosave")
            $aCONFIG[$g__ePDFCreator_CONFIG_UseAutoSaveDirectory] = .cOption("UseAutosaveDirectory")
            $aCONFIG[$g__ePDFCreator_CONFIG_AutoSaveDirectory] = .cOption("AutosaveDirectory")
            $aCONFIG[$g__ePDFCreator_CONFIG_AutoSaveFilename] = .cOption("AutosaveFilename")
            $aCONFIG[$g__ePDFCreator_CONFIG_AutoSaveFormat] = .cOption("AutosaveFormat")
            ; $aCONFIG[$g__ePDFCreator_CONFIG_] =
        EndWith

        Return $aCONFIG
    EndIf
EndFunc   ;==>_PDFCreator_Config_GetCurrent

Func _PDFCreator_Config_Set($aCONFIG)
    __PDFCreator_ObjCreate()
    If @error Then
        Return SetError(@error)
    Else
        If Not IsObj($g__oPDFCreator) Then MsgBox(0, 'Error', 'Not IsObj($g__oPDFCreator)')
        With $g__oPDFCreator
            .cVisible = $aCONFIG[$g__ePDFCreator_CONFIG_Visible]
            .cDefaultprinter = $aCONFIG[$g__ePDFCreator_CONFIG_DefaultPrinter]
            .cPrinterStop = $aCONFIG[$g__ePDFCreator_CONFIG_PrinterStop]
            .cOption("UseAutosave") = $aCONFIG[$g__ePDFCreator_CONFIG_UseAutoSave]
            .cOption("UseAutosaveDirectory") = $aCONFIG[$g__ePDFCreator_CONFIG_UseAutoSaveDirectory]
            .cOption("AutosaveDirectory") = $aCONFIG[$g__ePDFCreator_CONFIG_AutoSaveDirectory]
            .cOption("AutosaveFilename") = $aCONFIG[$g__ePDFCreator_CONFIG_AutoSaveFilename]
            .cOption("AutosaveFormat") = $aCONFIG[$g__ePDFCreator_CONFIG_AutoSaveFormat]
            ;  = $aCONFIG[$g__ePDFCreator_CONFIG_] =
        EndWith

    EndIf
EndFunc   ;==>_PDFCreator_Config_Set
#EndRegion PDFCreator.au3 - Functions CONFIG

I also received a lot of concepts based on the mode of action different libraries (Debenu, Chillkat), ie. The way the declaration of variables, parameter, or a return results ie in SmtpMailer.au3

Reveal hidden contents

#Region UDF Functions - COM Error Handler
Func _INetSmtpMailCom_ErrObjInit($bParam = Default)
    Local Static $oINetSmtpMailCom_Error = Default
    If $bParam == 'CleanUp' And $oINetSmtpMailCom_Error <> Default Then
        $oINetSmtpMailCom_Error = ''
        Return $oINetSmtpMailCom_Error
    EndIf
    If $oINetSmtpMailCom_Error = Default Then
        $oINetSmtpMailCom_Error = ObjEvent("AutoIt.Error", "_INetSmtpMailCom_ErrFunc")
    EndIf
    Return $oINetSmtpMailCom_Error
EndFunc   ;==>_INetSmtpMailCom_ErrObjInit

Func _INetSmtpMailCom_ErrObjCleanUp()
    _INetSmtpMailCom_ErrObjInit('CleanUp')
EndFunc   ;==>_INetSmtpMailCom_ErrObjCleanUp

Func _INetSmtpMailCom_ErrHexNumber($vData = Default)
    Local Static $vReturn = 0
    If $vData <> Default Then $vReturn = $vData
    Return $vReturn
EndFunc   ;==>_INetSmtpMailCom_ErrHexNumber

Func _INetSmtpMailCom_ErrDescription($sData = Default)
    Local Static $sReturn = ''
    If $sData <> Default Then $sReturn = $sData
    Return $sReturn
EndFunc   ;==>_INetSmtpMailCom_ErrDescription

Func _INetSmtpMailCom_ErrFunc()
    _INetSmtpMailCom_ErrObjInit()
    _INetSmtpMailCom_ErrHexNumber(Hex(_INetSmtpMailCom_ErrObjInit().number, 8))
    _INetSmtpMailCom_ErrDescription(StringStripWS(_INetSmtpMailCom_ErrObjInit().description, 3))
    ConsoleWrite("### COM Error !  Number: " & _INetSmtpMailCom_ErrHexNumber() & "   ScriptLine: " & _INetSmtpMailCom_ErrObjInit().scriptline & "   Description:" & _INetSmtpMailCom_ErrDescription() & @LF)
    SetError(1); something to check for when this function returns
    Return
EndFunc   ;==>_INetSmtpMailCom_ErrFunc

#EndRegion UDF Functions - COM Error Handler

How well I remember and as far as I understand, it's all about being here right now talking, we derive in part from the concept that @Valik, liked to call "API"

EDIT: Am I right on this?

Edited July 10, 2015 by mLipok

guinness · July 10, 2015

On 7/10/2015 at 2:56 PM, mLipok said:
Since I took a lot of programming style of @guinness

Just sharing the knowledge

On 7/10/2015 at 2:56 PM, mLipok said:
How well I remember and as far as I understand, it's all about being here right now talking, we derive in part from the concept that @Valik, liked to call "API"
EDIT: Am I right on this?

Yes, but his version is slightly different in that it only works with a single "data store", whereas this can be created with many by calling the "constructor"

xroot · July 10, 2015

Here is my take on simple OOps in Autoit.

Func ObjErrFunc()
    Msgbox(0,"*COM ERROR*",$ObjErr.description&@LF&$ObjErr.windescription&"Line "&$ObjErr.scriptline)
Endfunc



Func Person($sName, $iAge)
    $sd.Add($sd.Count,$sName)     ;Property
    $sd.Add($sd.Count,$iAge)      ;Property
    Return $sd.Items              ;Array Properties
EndFunc



Func Person_SetName(ByRef $hPerson, $sName)
    $hPerson[uBound($hPerson) - 2] = $sName

EndFunc



Func Person_GetName(ByRef $hPerson)
    Return $hPerson[uBound($hPerson) - 2]
EndFunc



Func Person_SetAge(ByRef $hPerson, $iAge)
    $hPerson[uBound($hPerson) - 1] = $iAge

EndFunc



Func Person_ToString(ByRef $hPerson)
    Return StringFormat('Name: %s, Age: %i', $hPerson[uBound($hPerson) - 2], $hPerson[uBound($hPerson) - 1])
Endfunc



    global $ObjErr = ObjEvent("AutoIt.Error","ObjErrFunc")
    global $sd     = ObjCreate("Scripting.Dictionary")

    local $hP1 = Person('John', 30)
    MsgBox(64, 'Person 1', Person_ToString($hP1))

    Local $hP2 = Person('James', 36)
    MsgBox(64, 'Person 2', Person_ToString($hP2))

    Person_SetAge($hP2, 45)
    MsgBox(64,'Person 2 - Revised',Person_ToString($hP2))

    Person_SetName($hP1, 'Michael')
    MsgBox(64,'Person 1 - Revised',Person_ToString($hP1))

    MsgBox(64,'Get Name Person 1',Person_GetName($hP1))

    Local $hP3 = Person('Amanda', 35)
    MsgBox(64, 'Person 3', Person_ToString($hP3))

This way I can add any number of Name's and Age's.

guinness · July 10, 2015

On 7/10/2015 at 4:52 PM, xroot said:
This way I can add any number of Name's and Age's

I think you misunderstood the purpose. Why would a Person for example have multiple ages? They wouldn't. How does your example translate from something like this?

// Java - Person example
class Person {
    // The underscore is to denote they're member variables, as I hate writing this all the time
    private int _age;
    private String _name;
    
    public Person(String name, int age) {
        _age = age;
        _name = name;
    }
    
    public int getAge() {
        return _age;
    }
    
    public String getName() {
        return _name;
    }
    
    public void setAge(int age) {
        _age = age;
    }
    
    public void setName(String name) {
        _name = name;
    }
    
    @Override
    public String toString() {
        return String.format("Name: %s, Age: %d", _name, _age);
    }
}

guinness · July 10, 2015

Or in C#

// C# - Person example
class Person 
{
    // Properties. How lovely these are! =)
    public int Age = { get; set; }
    public string Name = { get; set; }
    
    public Person(string name, int age)
    {
        Age = age;
        Name = name;
    }
        
    public override string ToString()
    {
        return String.Format("Name: %s, Age: %d", Name, Age);
    }
}

mLipok · July 10, 2015

On 7/10/2015 at 4:09 PM, guinness said:
Just sharing the knowledge

Thanks for the correction (as usual language barrier took its toll)

On 7/10/2015 at 4:09 PM, guinness said:
Yes, but his version is slightly different in that it only works with a single "data store", whereas this can be created with many by calling the "constructor"

You mean that @Valik example can open only single SciTE and work only with this single instance ?

btw.

I like the ~~concenct~~ concept of using $PERSON_GUID in your example

Edited July 11, 2015 by mLipok
wording

guinness · July 10, 2015

Lets assume that his example can only spawn one SciTE. In that case if I wanted a second process of SciTE it wouldn't be possible. My approach you can have that.

I use the GUID as a means to ensure that if a user passes an array with the exact dimensions, that it shouldn't fail as I have a check of whether one element contains the GUID. It's not full-proof, but better than nothing.

AdmiralAlkex · July 12, 2015

On 7/10/2015 at 1:34 PM, Jefrey said:
Truly, I would write that using AutoItObject, but I thought that putting an additional DLL just for generating JSONs would sound strange. So I started coding it so on my own...

If you are talking about the autoitobject.dll file, then that's for debugs or something, you don't need that file. Just skip it.

Edited July 12, 2015 by AdmiralAlkex

guinness · April 15, 2017

Even after nearly 2 years, I still like this approach to writing AutoIt code

Sign In

OOP-like approach in AutoIt

Recommended Posts

guinness

Jefrey

guinness

Jefrey

guinness

jaberwacky

guinness

JohnOne

guinness

Jefrey

guinness

mLipok

guinness

xroot

guinness

guinness

mLipok

guinness

AdmiralAlkex

guinness

Create an account or sign in to comment

Create an account

Sign in

Recently Browsing 0 members

Similar Content

COM "The requested action with this object has failed."

_ArrayCopyRange

Rearrange array columns based on first row's values

Get the duplicates value of Array

Function not working with array

Browse

AutoIt Resources

Release

Beta