Is there a easy way to parse string to array?

[squadjot]

Hi everybody

I need to read a multidimensional array, declared as a string, written in a ini file.

Like this:

//settings.ini
[Main]
areas=[[0,10,50,50],[500,560,50,50]]

When i read the value with IniRead, it's a string.
Is there an easy way to convert that to valid arrays?

 

Thanks

 

[JohnOne]

Couple of passes with Stringsplit could do it.

Or probably a Regexp warlock could do it in one.

Edited December 7, 2015 by JohnOne

[Danyfirex]

just for fun.

#include <Array.au3>
Local $sString = "[[0,10,50,50],[500,560,50,50]]"




Local $aArray = _Make2Array($sString)


_ArrayDisplay($aArray)

Func _Make2Array($sString)
    Local $aReg = StringRegExp($sString, "\d{1,}", 3)
    Local $aArray[2][UBound($aReg) / 2]
    For $i = 0 To (UBound($aReg) - 1) / 2
        $aArray[0][$i] = $aReg[($i)]
        $aArray[1][$i] = $aReg[($i) + (UBound($aReg)) / 2]
    Next
    Return $aArray
EndFunc   ;==>_Make2Array

Saludos

[spudw2k]

@‌DanyFirex

Quick n dirty...not bad.  My only complaint...it's too tailored for this particular scenario.  
There is nothing wrong with making a very, very specific function...but the modular mindset in me is twitching.
 

[Danyfirex]

@‌DanyFirex

Quick n dirty...not bad.  My only complaint...it's too tailored for this particular scenario.  
There is nothing wrong with making a very, very specific function...but the modular mindset in me is twitching.
 

dirty is so much sweet for that script lol

Saludos

[mikell]

My 2 cents, for the concept and w/o error checking

#include <Array.au3>

Local $sString = "[[0,10,50,50],[500,560,50,50]]"

Local $aArray = _Make2Array($sString)
_ArrayDisplay($aArray)


Func _Make2Array($s)
    $s = StringRegExpReplace($s, '[\[\]]{2}', "")
    Local $s1 = StringSplit($s, "],[", 1), $s2
    StringReplace($s1[1], ",", ",")
    Local $res[$s1[0]][@extended+1]
    For $i = 1 to $s1[0]
         $s2 = StringSplit($s1[$i], ",")
         For $j = 1 to $s2[0]
              $res[$i-1][$j-1] = $s2[$j]
         Next
    Next
    Return $res
EndFunc

Edit
Hehe, JO was right about StringSplit, but I don't know a one-liner regex able to return a 2D array 

Edited December 7, 2015 by mikell

[jchd]

Not with the current PCRE implementation, sadly. Nor with the current ReDim which (sadly again) doesn't allow various dimension combinations. Hence pedestrian solutions only.

[Luigi]

Hi, try example_6 from FRED.

[jdelaney]

You can get around various dimensional combinations by using array of arrays, rather than just array of strings/integers.

#include <Array.au3>
Local $sString = "[[0,10,50,50],[500,560,50,50]]"
$a = StringRegExp($sString,"\[([\d,]+)\]",3)
For $i = 0 To UBound($a)-1
    $a[$i] = StringSplit($a[$i],",",2)
    _ArrayDisplay($a[$i])
Next

Local $sString = "[[0,10,50,50],[560,50,50]]"
$a = StringRegExp($sString,"\[([\d,]+)\]",3)
For $i = 0 To UBound($a)-1
    $a[$i] = StringSplit($a[$i],",",2)
    _ArrayDisplay($a[$i])
Next

 

Edited December 8, 2015 by jdelaney

[iamtheky]

Does it matter if the array is 2D, as long you read them out where you need them?

$count = 0
$sOut = ""

Local $sString = "[[0,10,50,50],[500,560,50,50]]"

$aString = stringsplit(stringreplace(stringreplace($sString , "]" , "") , "[" , "") , "," , 2)

For $i = 0 to ubound($aString) - 1
    $count += 1
    $sOut &= $aString[$i] & @TAB
    If $count = (ubound($aString) / 2) Then $sOut &= @LF
Next

msgbox(0, '' , $sOut)

 

[Malkey]

This modified mikell's example allows for a 2D array with varying number of columns in rows.

#include <Array.au3>

Local $sString = '[[0,10,50,50],["L", "o", "n", "g", "e", "s", "t"],["The least","number of columns","in a row"],[500,560,50,50,5]] '
Local $aArray = _Make2ArrayEx($sString)
_ArrayDisplay($aArray)


Func _Make2ArrayEx($s)
    $s = StringRegExpReplace($s, '[\[\]]{2}', "")
    Local $s1 = StringSplit($s, "],[", 1), $s2
    StringReplace($s1[1], ",", ",")
    Local $iUB_Cols = @extended + 1
    Local $res[$s1[0]][$iUB_Cols]
    For $i = 1 To $s1[0]
        $s2 = StringSplit($s1[$i], ",")
        If $s2[0] > $iUB_Cols Then
            $iUB_Cols = $s2[0]
            ReDim $res[$s1[0]][$iUB_Cols]
        EndIf
        For $j = 1 To $s2[0]
            $res[$i - 1][$j - 1] = $s2[$j]
        Next
    Next
    Return $res
EndFunc   ;==>_Make2ArrayEx

 

[mLipok]

Hi, try example_6 from FRED.

In your FRED opening post there are broken links.
Can you fix it ?

 

[jchd]

BTW this format is very similar to a CSV is you remove the leading and trailing square brakets and consider '],[' as a line separator. This modulo spurious spacing, of course.

[Luigi]

mLipok, you write, thanks for the alert.

but, the UDF link is work, try this.

[mikell]

A variant of Malkey's variant  
Not sure it's faster than several Redims

#include <Array.au3>

Local $sString = '[[0,10,50,50],["L", "o", "n", "g", "e", "s", "t"],["The least","number of columns","in a row"],[500,560,50,50,5]] '

Local $aArray = _Make2Array($sString)
_ArrayDisplay($aArray)


Func _Make2Array($s)
    $s = StringRegExpReplace($s, '[\[\]]{2}', "")
    Local $s1 = StringSplit($s, "],[", 1), $s2, $n
    For $i = 1 to $s1[0]
        StringReplace($s1[$i], ",", ",")
        $n = ($n < @extended+1) ? @extended+1 : $n
    Next
    Local $res[$s1[0]][$n]
    For $i = 1 to $s1[0]
         $s2 = StringSplit($s1[$i], ",")
         For $j = 1 to $s2[0]
              $res[$i-1][$j-1] = $s2[$j]
         Next
    Next
    Return $res
EndFunc

 

[jguinch]

Here is my small contribution :

#include <Array.au3>

Local $sString = '[[0,10,50,50],["L", "o", 50, "g", "e", "s", "t"],["The least","numbers of columns","in a row"],[500,560,50,50,5], ["That''s all"]] '
Local $aArray = _Make2Array($sString)
_ArrayDisplay($aArray)

Func _Make2Array($s)
    Local $aLines = StringRegExp($s, "(?<=[\[,])\s*\[(.*?)\]\s*[,\]]", 3), $iCountCols = 0
    For $i = 0 To UBound($aLines) - 1
        $aLines[$i] = StringRegExp($aLines[$i], "(?:^|,)\s*(?|'([^']*)'|""([^""]*)""|(.*?))(?=\s*(?:,|$))", 3)
        If UBound($aLines[$i]) > $iCountCols Then $iCountCols = UBound($aLines[$i])
    Next
    Local $aRet[UBound($aLines)][$iCountCols]
    For $y = 0 To UBound($aLines) - 1
        For $x = 0 To UBound($aLines[$y]) - 1
            $aRet[$y][$x] = ($aLines[$y])[$x]
        Next
    Next
    Return $aRet
EndFunc