Read output of an active command prompt window - (Moved)

[anit]

Hi,

I am trying to read the console output of an "active" command prompt window. The following code that I tested with, causes the cmd window to close at the very same time when it is run. I want the command prompt window to stay open and be able to read the output of the cmd window. Please tell me how to achieve this.

$pid=Run("cmd.exe", "", @SW_SHOWMAXIMIZED, $STDIN_CHILD)

Sleep(2000)
$data = StdoutRead($pid)
ConsoleWrite("Debug:" & $data & @LF)

 

Thanks,

Anit

[careca]

#AutoIt3Wrapper_Au3Check_Parameters=-d -w 1 -w 2 -w 3 -w- 4 -w 5 -w 6 -w- 7
#include <Misc.au3>
#include <WinAPISys.au3>
Opt("WinTitleMatchMode", 2) ;1=start, 2=subStr, 3=exact, 4=advanced, -1 to -4=Nocase
Run('cmd')
Global $hCmd = 0, $cmdtext, $cmdtext2
Do
    If _IsPressed('01') Then
        $hCmd = WinGetTitle("[active]")
    EndIf
    Sleep(100)
Until $hCmd <> ''
SendKeepActive($hCmd)
$cmdtext2 = ClipGet()
Send( "! es{Enter}" )
$cmdtext = ClipGet()
ClipPut($cmdtext2)
MsgBox(64, '$Read', $cmdtext)

The only thing i can help with.

See this post

Edited May 26, 2020 by careca

[Melba23]

Moved to the appropriate forum, as the Developer General Discussion forum very clearly states:

  Quote

General development and scripting discussions.

---

Do not create AutoIt-related topics here, use the AutoIt General Help and Support or AutoIt Technical Discussion forums.

Expand  

Moderation Team

[argumentum]

hmmm, there are 2

Example()

Func Example()
    Local $iPID = Run(@ComSpec & " /k DIR", @SystemDir, @SW_SHOW, 6) ; 6 = BitOR($STDERR_CHILD, $STDOUT_CHILD)
    Local $sOutput = ""
    While 1
        $sOutput &= StdoutRead($iPID)
        If @error Then ; Exit the loop if the process closes or StdoutRead returns an error.
            ExitLoop
        EndIf
        If $sOutput Then MsgBox(0, "Stdout Read:", $sOutput)
        $sOutput = ""
    WEnd

    $sOutput = ''
    While 1
        $sOutput &= StderrRead($iPID)
        If @error Then ; Exit the loop if the process closes or StderrRead returns an error.
            ExitLoop
        EndIf
        If $sOutput Then MsgBox(0, "Stderr Read:", $sOutput)
        $sOutput = ""
    WEnd
    MsgBox(0, "Done", "done, closing the script.")
EndFunc   ;==>Example

1. if you pipe the output to a file, you don't see it. You are piping to your script. But once you have the text you can display in a GUI of your own.

2. The cmd.exe /K yourCommand should keep the window open and shown with the above script, but it does not. @Melba23 this is a bug  

[argumentum]

...moreover, it works as expected in v3.2.12.1 but fails v3.3.6.1 onward, so is not something new.
Is this a feature given that showing the windows does nothing practical or is it a bug @Jon ?

[Nine]

Here a different approach, similar of @careca :

#include <Constants.au3>

Opt("MustDeclareVars", 1)
Opt("SendKeyDelay", 0)

If Not ProcessExists("cmd.exe") Then
  Run("cmd.exe")
  ProcessWait("cmd.exe")
EndIf
Local $hDOS = WinGetHandle("[CLASS:ConsoleWindowClass]")
If Not $hDOS Then Exit MsgBox($MB_SYSTEMMODAL, "", "Console not found")
WinActivate($hDOS)
MsgBox ($MB_SYSTEMMODAL,"",Example2 ($hDOS, "dir"))

Func Example2($hWnd, $sCmd, $iDelay = 100)
  ControlSend($hWnd, "", "", "cls & " & $sCmd & @CRLF)
  Sleep ($iDelay)
  Opt("SendKeyDelay", 50)
  ControlSend($hWnd, "", "","! mt{Enter}") ; french OS
  Opt("SendKeyDelay", 0)
  Return ClipGet()
EndFunc   ;==>Example2

@argumentum  I personally do not think it is a bug.  I believe it is a normal behavior for a child process to close when its parent prematurely ends.  Especially if the parent is hooked to the child stream as any child ConsoleWrite will error out.

[argumentum]

@Nine, do execute the code I posted with v3.2.12.1 then you'll see that the way it runs now is not what the help manual explains. 
@SW_SHOW is supposed to show the CUI and the " /K " should keep the CUI open, and unless closed, you can manually run a command and it'll show in the MsgBox. 

[anit]

@careca Thanks! I tried your code snippet and it serves the purpose! by the way, what does Send( "! es{Enter}" ) do?

[careca]

Well, it is Alt key, then E for Edit menu item, then S for Select all submenu item. Enter places the text in clipboard.

It is curious that when i try that combination of keys, i cannot bring the menu up.

But still, it works.

[seadoggie01]

@careca There's a space in the code, Alt + Space brings up a hidden menu  You can see it by right clicking on the title bar as well.

[careca]

Ah the space! thanks.

[mLipok]

@anit do you already try  @Mat 's console.au3 UDF:

https://github.com/MattDiesel/au3-console

?

 

Edited May 27, 2020 by mLipok