ListView + ImageList for GroupHeader ( LVSIL_GROUPHEADER )

[mLipok]

In this document:
https://learn.microsoft.com/en-us/windows/win32/controls/lvm-setimagelist

 

I saw that LVSIL_GROUPHEADER can be used.

After a quick overview and as far as I can see there is no way to use function like _GUICtrlListView_**ImageList() for GroupHeader.
Anybody can confirm that ?

 

[mLipok]

My research  led me to:

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <GuiImageList.au3>
#include <WinAPIGdi.au3>

_Example()

Func _Example()

    Local $hGUI = GUICreate("LVSIL_GROUPHEADER Example", 500, 300)
    #forceref $hGUI

    Local $idListView = GUICtrlCreateListView("Name|Value", 10, 10, 480, 250)
    Local $hListView = GUICtrlGetHandle($idListView)

    ; Enable group view
    _SendMessage($hListView, $LVM_ENABLEGROUPVIEW, True, 0)

    ; Create ImageList for LVSIL_GROUPHEADER
    Local $hImageList = _GUIImageList_Create(16, 16)

    Local $hIcon = _WinAPI_LoadIcon(0, $IDI_INFORMATION)

    ; Image index = 0
    _GUIImageList_AddIcon($hImageList, $hIcon)

    ; Assign ImageList to GROUP HEADER slot
    _SendMessage($hListView, $LVM_SETIMAGELIST, $LVSIL_GROUPHEADER, $hImageList)

    ; Create group using iTitleImage
    Local $tagLVGROUP = _
            "uint cbSize;" & _
            "uint mask;" & _
            "ptr pszHeader;" & _
            "int cchHeader;" & _
            "ptr pszFooter;" & _
            "int cchFooter;" & _
            "int iGroupId;" & _
            "uint stateMask;" & _
            "uint state;" & _
            "uint uAlign;" & _
            "int iTitleImage"

    Local $sHeader = "Group A"

    Local $tText = DllStructCreate("wchar[" & StringLen($sHeader) + 1 & "]")
    DllStructSetData($tText, 1, $sHeader)

    Local $tGroup = DllStructCreate($tagLVGROUP)

    DllStructSetData($tGroup, "cbSize", DllStructGetSize($tGroup))

    ; Use HEADER + GROUPID + TITLEIMAGE
    DllStructSetData($tGroup, "mask", _
            BitOR($LVGF_HEADER, $LVGF_GROUPID, $LVGF_TITLEIMAGE))

    DllStructSetData($tGroup, "pszHeader", DllStructGetPtr($tText))
    DllStructSetData($tGroup, "cchHeader", StringLen($sHeader))

    DllStructSetData($tGroup, "iGroupId", 1)

    ; Use image index 0 from LVSIL_GROUPHEADER
    DllStructSetData($tGroup, "iTitleImage", 0)

    ; Insert group
    _SendMessage($hListView, $LVM_INSERTGROUP, -1, DllStructGetPtr($tGroup))

    ; Add item into group
    Local $iItem = _GUICtrlListView_AddItem($hListView, "Item 1")

    _GUICtrlListView_AddSubItem($hListView, $iItem, "123", 1)

    _GUICtrlListView_SetItemGroupID($hListView, $iItem, 1)

    GUISetState()

    While GUIGetMsg() <> $GUI_EVENT_CLOSE
    WEnd

EndFunc

But I has no positive effect.

 

Here I saw some positive results:
https://www.vbforums.com/showthread.php?804969-PARTIALLY-RESOLVED-Listview-Grouping-in-Virtual-Mode

I mean I looking for such result (image in Headers and image in Groups):
http://vbrichclient.com/Downloads/OwnerDrawnGroupList.png

Edited May 12 by mLipok

[mLipok]

Another not working example

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <GuiImageList.au3>
#include <WinAPIGdi.au3>

_Example()

Func _Example()

    Local $hGUI = GUICreate("GroupHeaderImageList", 500, 300)
    #forceref $hGUI

    Local $idListView = GUICtrlCreateListView("Name|Value", 10, 10, 480, 250)
    Local $hListView = GUICtrlGetHandle($idListView)

    ; Enable group view
    _SendMessage($hListView, $LVM_ENABLEGROUPVIEW, True, 0)

    ; =====================================================
    ; Create ImageList
    ; =====================================================

    Local $hImageList = _GUIImageList_Create(16, 16)

    Local $hIcon = _WinAPI_LoadIcon(0, $IDI_INFORMATION)

    ; Add icon to ImageList
    _GUIImageList_AddIcon($hImageList, $hIcon)

    ; =====================================================
    ; Set Group Header ImageList
    ; =====================================================

    ListView_SetGroupHeaderImageList($hListView, $hImageList)

    ; =====================================================
    ; Get Group Header ImageList
    ; =====================================================

    Local $hReturned = ListView_GetGroupHeaderImageList($hListView)

    ConsoleWrite("Original : " & $hImageList & @CRLF)
    ConsoleWrite("Returned : " & "0x" & Hex($hReturned) & @CRLF)

    ; =====================================================
    ; Create group
    ; =====================================================

    Local $tagLVGROUP = _
            "uint cbSize;" & _
            "uint mask;" & _
            "ptr pszHeader;" & _
            "int cchHeader;" & _
            "ptr pszFooter;" & _
            "int cchFooter;" & _
            "int iGroupId;" & _
            "uint stateMask;" & _
            "uint state;" & _
            "uint uAlign;" & _
            "int iTitleImage"

    Local $sHeader = "Group A"

    Local $tText = DllStructCreate("wchar[" & StringLen($sHeader) + 1 & "]")
    DllStructSetData($tText, 1, $sHeader)

    Local $tGroup = DllStructCreate($tagLVGROUP)

    DllStructSetData($tGroup, "cbSize", DllStructGetSize($tGroup))

    DllStructSetData($tGroup, "mask", _
            BitOR($LVGF_HEADER, $LVGF_GROUPID, $LVGF_TITLEIMAGE))

    DllStructSetData($tGroup, "pszHeader", DllStructGetPtr($tText))
    DllStructSetData($tGroup, "cchHeader", StringLen($sHeader))

    DllStructSetData($tGroup, "iGroupId", 1)

    ; Use image index 0
    DllStructSetData($tGroup, "iTitleImage", 0)

    ; Insert group
    _SendMessage($hListView, $LVM_INSERTGROUP, -1, DllStructGetPtr($tGroup))

    ; =====================================================
    ; Add item into group
    ; =====================================================

    Local $iItem = _GUICtrlListView_AddItem($hListView, "Item 1")

    _GUICtrlListView_AddSubItem($hListView, $iItem, "123", 1)

    _GUICtrlListView_SetItemGroupID($hListView, $iItem, 1)

    GUISetState()

    While GUIGetMsg() <> $GUI_EVENT_CLOSE
    WEnd

EndFunc

; #FUNCTION# ===================================================================
; Name...........: ListView_SetGroupHeaderImageList
; Description ...: Sets the ImageList used by group headers.
; ==============================================================================
Func ListView_SetGroupHeaderImageList($hListView, $hImageList)

    Return _SendMessage( _
            $hListView, _
            $LVM_SETIMAGELIST, _
            $LVSIL_GROUPHEADER, _
            $hImageList)

EndFunc

; #FUNCTION# ===================================================================
; Name...........: ListView_GetGroupHeaderImageList
; Description ...: Gets the ImageList used by group headers.
; ==============================================================================
Func ListView_GetGroupHeaderImageList($hListView)

    Return _SendMessage( _
            $hListView, _
            $LVM_GETIMAGELIST, _
            $LVSIL_GROUPHEADER, _
            0)

EndFunc

 

[pixelsearch]

Hello mLipok
What happens if you create the LVGROUP structure with all its members positioned exactly as shown on msdn ?
Because in your structure, it seems to me that the member iTitleImage isn't correctly placed :

Local $tagLVGROUP = _
    "uint cbSize;" & _
    "uint mask;" & _
    "ptr pszHeader;" & _
    "int cchHeader;" & _
    "ptr pszFooter;" & _
    "int cchFooter;" & _
    "int iGroupId;" & _
    "uint stateMask;" & _
    "uint state;" & _
    "uint uAlign;" & _
    "int iTitleImage" ; <=== ?

Here is the msdn structure adapted to AutoIt, showing plenty of members between uAlign and iTitleImage :

Local $tagLVGROUP = _
    "uint cbSize;" & _
    "uint mask;" & _
    "ptr pszHeader;" & _
    "int cchHeader;" & _
    "ptr pszFooter;" & _
    "int cchFooter;" & _
    "int iGroupId;" & _
    "uint stateMask;" & _
    "uint state;" & _
    "uint uAlign;" & _
    "ptr pszSubtitle;" & _
    "uint cchSubtitle;" & _
    "ptr pszTask;" & _
    "uint cchTask;" & _
    "ptr pszDescriptionTop;" & _
    "uint cchDescriptionTop;" & _
    "ptr pszDescriptionBottom;" & _
    "uint cchDescriptionBottom;" & _
    "int iTitleImage;" & _
    "int iExtendedImage;" & _
    "int iFirstItem;" & _
    "uint cItems;" & _
    "ptr pszSubsetTitle;" & _
    "uint cchSubsetTitle"

If it works, then maybe it could be the same problem in your other script related to the LVGROUP structure
As I'm not a structure expert at all, I have no idea if it will be useful (or even accurate)

Fingers crossed that it may solve your issues

[water]

30 minutes ago, pixelsearch said:

As I'm not a structure expert at all, I have no idea if it will be useful (or even accurate)

Maybe the H2Au3 tool from the german forum helps to create structures for AutoIt 🤔It's old, it's beta and far from perfect, but it might save you a few minutes  
https://autoit.de/thread/23604-h2au3/?postID=192084&highlight=h2au3#post192084

Here is the translated post:
 

Hi,

I’d like to introduce you to a tool that lets you convert C constants, function declarations, and structure definitions into AutoIt code.

The program is still in the beta stage and will eventually be able to translate entire C header files (not everything, but what it can handle).
It can also be used to translate function declarations and structure definitions from the MSDN Developer Library (this already works quite well).
Since h2au3 isn’t perfect, you’ll need to make some manual corrections here and there, such as the last parameter in the example below, which represents a structure (BLENDFUNCTION).

The preview version is attached.

Usage:

Clipboard:
Start h2au3, copy a function/structure from MSDN or a C header file, e.g., AlphaBlend. Copy the function syntax to the clipboard, select what you want to convert—in this case, a function or simply select “All”—and press “F5.” Done.

Compiling a header file:
Select a C header file via the “File | Open” menu.
Select the “Tools | Start” menu item or press “F5”. Done.
Quick alternative: Drag and drop a C header file into the window. Done.

MSDN Search:
Select the menu item “View | Search Bar.”
A toolbar with an input field will appear.
Enter the name of a function or structure in the input field and press the “Search” button or “F3.” Done

Translated with DeepL.com (free version)

 

[mLipok]

11 hours ago, pixelsearch said:

Here is the msdn structure adapted to AutoIt, showing plenty of members between uAlign and iTitleImage :

Local $tagLVGROUP = _
    "uint cbSize;" & _
    "uint mask;" & _
    "ptr pszHeader;" & _
    "int cchHeader;" & _
    "ptr pszFooter;" & _
    "int cchFooter;" & _
    "int iGroupId;" & _
    "uint stateMask;" & _
    "uint state;" & _
    "uint uAlign;" & _
    "ptr pszSubtitle;" & _
    "uint cchSubtitle;" & _
    "ptr pszTask;" & _
    "uint cchTask;" & _
    "ptr pszDescriptionTop;" & _
    "uint cchDescriptionTop;" & _
    "ptr pszDescriptionBottom;" & _
    "uint cchDescriptionBottom;" & _
    "int iTitleImage;" & _
    "int iExtendedImage;" & _
    "int iFirstItem;" & _
    "uint cItems;" & _
    "ptr pszSubsetTitle;" & _
    "uint cchSubsetTitle"

 

 

 

expandcollapse popup

;~ https://www.autoitscript.com/forum/topic/213683-listview-imagelist-for-groupheader-lvsil_groupheader

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <GuiImageList.au3>
#include <WinAPIGdi.au3>

Global Const $LVSIL_GROUPHEADER = 2

_Example()

Func _Example()

    Local $hGUI = GUICreate("GroupHeaderImageList", 500, 300)
    #forceref $hGUI

    Local $idListView = GUICtrlCreateListView("Name|Value", 10, 10, 480, 250)
    Local $hListView = GUICtrlGetHandle($idListView)

    ; Enable group view
    _SendMessage($hListView, $LVM_ENABLEGROUPVIEW, True, 0)

    ; =====================================================
    ; Create ImageList
    ; =====================================================

    Local $hImageList = _GUIImageList_Create(16, 16)

    Local $hIcon = _WinAPI_LoadIcon(0, $IDI_INFORMATION)

    ; Add icon to ImageList
    _GUIImageList_AddIcon($hImageList, $hIcon)

    ; =====================================================
    ; Set Group Header ImageList
    ; =====================================================

    ListView_SetGroupHeaderImageList($hListView, $hImageList)

    ; =====================================================
    ; Get Group Header ImageList
    ; =====================================================

    Local $hReturned = ListView_GetGroupHeaderImageList($hListView)

    ConsoleWrite("Original : " & $hImageList & @CRLF)
    ConsoleWrite("Returned : " & "0x" & Hex($hReturned) & @CRLF)

    ; =====================================================
    ; Create group
    ; =====================================================

    Local $tagLVGROUP = _
            "uint cbSize;" & _
            "uint mask;" & _
            "ptr pszHeader;" & _
            "int cchHeader;" & _
            "ptr pszFooter;" & _
            "int cchFooter;" & _
            "int iGroupId;" & _
            "uint stateMask;" & _
            "uint state;" & _
            "uint uAlign;" & _
            "ptr pszSubtitle;" & _
            "uint cchSubtitle;" & _
            "ptr pszTask;" & _
            "uint cchTask;" & _
            "ptr pszDescriptionTop;" & _
            "uint cchDescriptionTop;" & _
            "ptr pszDescriptionBottom;" & _
            "uint cchDescriptionBottom;" & _
            "int iTitleImage;" & _
            "int iExtendedImage;" & _
            "int iFirstItem;" & _
            "uint cItems;" & _
            "ptr pszSubsetTitle;" & _
            "uint cchSubsetTitle"
    Local $sHeader = "Group A"

    Local $tText = DllStructCreate("wchar[" & StringLen($sHeader) + 1 & "]")
    DllStructSetData($tText, 1, $sHeader)

    Local $tGroup = DllStructCreate($tagLVGROUP)

    DllStructSetData($tGroup, "cbSize", DllStructGetSize($tGroup))

    DllStructSetData($tGroup, "mask", _
            BitOR($LVGF_HEADER, $LVGF_GROUPID, $LVGF_TITLEIMAGE))

    DllStructSetData($tGroup, "pszHeader", DllStructGetPtr($tText))
    DllStructSetData($tGroup, "cchHeader", StringLen($sHeader))

    DllStructSetData($tGroup, "iGroupId", 1)

    ; Use image index 0
    DllStructSetData($tGroup, "iTitleImage", 0)

    ; Insert group
    _SendMessage($hListView, $LVM_INSERTGROUP, -1, DllStructGetPtr($tGroup))

    ; =====================================================
    ; Add item into group
    ; =====================================================

    Local $iItem = _GUICtrlListView_AddItem($hListView, "Item 1")

    _GUICtrlListView_AddSubItem($hListView, $iItem, "123", 1)

    _GUICtrlListView_SetItemGroupID($hListView, $iItem, 1)

    GUISetState()

    While GUIGetMsg() <> $GUI_EVENT_CLOSE
    WEnd

EndFunc   ;==>_Example

; #FUNCTION# ===================================================================
; Name...........: ListView_SetGroupHeaderImageList
; Description ...: Sets the ImageList used by group headers.
; ==============================================================================
Func ListView_SetGroupHeaderImageList($hListView, $hImageList)

    Return _SendMessage( _
            $hListView, _
            $LVM_SETIMAGELIST, _
            $LVSIL_GROUPHEADER, _
            $hImageList)

EndFunc   ;==>ListView_SetGroupHeaderImageList

; #FUNCTION# ===================================================================
; Name...........: ListView_GetGroupHeaderImageList
; Description ...: Gets the ImageList used by group headers.
; ==============================================================================
Func ListView_GetGroupHeaderImageList($hListView)

    Return _SendMessage( _
            $hListView, _
            $LVM_GETIMAGELIST, _
            $LVSIL_GROUPHEADER, _
            0)

EndFunc   ;==>ListView_GetGroupHeaderImageList

Still not works well.

It sets and returns:

Quote

Original : 0x0497C2D0
Returned : 0x0497C2D0
 

But no images are displayed.

Edited 5 hours ago by mLipok

[Nine]

Here a working version :

expandcollapse popup

; From Nine (base code of mLipok)
#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <GuiImageList.au3>

Global Const $LVSIL_GROUPHEADER = 3
Global Const $tagLVGROUPEx = _
    "uint cbSize;" & _
    "uint mask;" & _
    "ptr pszHeader;" & _
    "int cchHeader;" & _
    "ptr pszFooter;" & _
    "int cchFooter;" & _
    "int iGroupId;" & _
    "uint stateMask;" & _
    "uint state;" & _
    "uint uAlign;" & _
    "ptr pszSubtitle;" & _
    "uint cchSubtitle;" & _
    "ptr pszTask;" & _
    "uint cchTask;" & _
    "ptr pszDescriptionTop;" & _
    "uint cchDescriptionTop;" & _
    "ptr pszDescriptionBottom;" & _
    "uint cchDescriptionBottom;" & _
    "int iTitleImage;" & _
    "int iExtendedImage;" & _
    "int iFirstItem;" & _
    "uint cItems;" & _
    "ptr pszSubsetTitle;" & _
    "uint cchSubsetTitle"

Local $tInfo = DllStructCreate("dword cbSize;dword dwMajorVersion;dword dwMinorVersion;dword dwBuildNumber;dword dwPlatformID;dword dwFlags;uint64 ullVersion;")
$tInfo.cbSize = DllStructGetSize($tInfo)
DllCall("ComCtl32.dll", "long", "DllGetVersion", "struct*", $tInfo)
If $tInfo.dwMajorVersion < 6 Then Exit ConsoleWrite("You need version 6 or higher" & @CRLF)

Example()

Func Example()
  Local $hGUI = GUICreate("GroupHeaderImageList", 500, 300)
  Local $idListView = GUICtrlCreateListView("Name|Value", 10, 10, 480, 250)
  Local $hListView = GUICtrlGetHandle($idListView)

  _GUICtrlListView_EnableGroupView($hListView)
  Local $hImageList = _GUIImageList_Create(16, 16, 5, 3)
  _GUIImageList_AddIcon($hImageList, @SystemDir & "\shell32.dll", 110)

  _SendMessage($hListView, $LVM_SETIMAGELIST, $LVSIL_GROUPHEADER, $hImageList)

  Local $sHeader = "Group A"
  Local $tText = DllStructCreate("wchar[" & StringLen($sHeader) + 1 & "]")
  DllStructSetData($tText, 1, $sHeader)
  Local $tGroup = DllStructCreate($tagLVGROUPEx)
  $tGroup.cbSize = DllStructGetSize($tGroup)
  $tGroup.mask = BitOR($LVGF_HEADER, $LVGF_GROUPID, $LVGF_TITLEIMAGE)
  $tGroup.pszHeader = DllStructGetPtr($tText)
  $tGroup.cchHeader = StringLen($sHeader)
  $tGroup.iGroupId = 1
  $tGroup.iTitleImage = 0

  _SendMessage($hListView, $LVM_INSERTGROUP, -1, DllStructGetPtr($tGroup))

  Local $iItem = _GUICtrlListView_AddItem($hListView, "Item 1")
  _GUICtrlListView_AddSubItem($hListView, $iItem, "123", 1)
  _GUICtrlListView_SetItemGroupID($hListView, $iItem, 1)

  GUISetState()

  While GUIGetMsg() <> $GUI_EVENT_CLOSE
  WEnd
EndFunc   ;==>Example

ps.  I eliminated all unnecessary code/comments to facilitate debugging.  

Edited 11 hours ago by Nine

[mLipok]

It works fine.

Big Thanks.

[mLipok]

When I talked to AI then it talks that not only
✔ iTitleImage
✔ LVSIL_GROUPHEADER

should works,

but also this following one
✔ iFirstItem
✔ cItems
✔ LVNI_SAMEGROUPONLY
 

I already get it to work with:
✔ iFirstItem
✔ cItems

But still have some issues with:

✔ LVNI_SAMEGROUPONLY

So would you be so nice and take a look also on: ListView LVM_GETNEXTITEM + LVNI_SAMEGROUPONLY

?

Edited 1 hour ago by mLipok