Validate if user entering the right email address format

[dannydy]

Hi, i've created a simple program, asking user to enter his/her email address, e.g dannyd_y@hotmail.com

Or user can enter multiple email addresses, dannyd_y@hotmail.com;dannyd_yq@yahoo.com.

Func mainlobby()
Global $msg, $receiver
local $sendemilbutton,$recipientsread,$recipientsenter

GUICreate($toolname,$width, $height, 500, 250, -1, $WS_EX_ACCEPTFILES) ; will create a dialog box that when displayed is centered
GUISetBkColor(0x6666FF)
$recipientsenter = GUICtrlCreateInput("", 10, 5, 250, 20)
$sendemilbutton = GUICtrlCreateButton("Send Email", 230, 128, 70, 25,-1,0x00000001)

GUISetState(@SW_SHOW)

do
$msg = GUIGetMsg()
Select
Case $msg = $sendemilbutton
if GUICtrlRead($recipientsenter) ="" Then
msgbox(16,"Email Not Input","Cannot Find Any Email")
Else
msgbox(0,"Email Input",GUICtrlRead($recipientsenter))
$receiver = GUICtrlRead($recipientsenter)
CreateMailItem()
EndIf
EndSelect
Until $msg = $GUI_EVENT_CLOSE
GUIDelete()
_Exit()

EndFunc

How do i validate if user is entering the right format. i've made some studies on this it seems like the right way of coding is using StringRegExp, but i coudlnt understand the regular expression pattern at all. Appreciate someone can help me. Many Thanks.

[kylomas]

dannydy,

You might do something like this (not tested)

expandcollapse popup

Func mainlobby()
    Global $msg, $receiver
    Local $sendemilbutton, $recipientsread, $recipientsenter, $aEmail

    GUICreate($toolname, $width, $height, 500, 250, -1, $WS_EX_ACCEPTFILES) ; will create a dialog box that when displayed is centered
    GUISetBkColor(0x6666FF)
    $recipientsenter = GUICtrlCreateInput("", 10, 5, 250, 20)
    $sendemilbutton = GUICtrlCreateButton("Send Email", 230, 128, 70, 25, -1, 0x00000001)

    GUISetState(@SW_SHOW)

    Do
        $msg = GUIGetMsg()
        Select
            Case $msg = $sendemilbutton
                If GUICtrlRead($recipientsenter) = "" Then
                    MsgBox(16, "Email Not Input", "Cannot Find Any Email")
                Else
                    MsgBox(0, "Email Input", GUICtrlRead($recipientsenter))
                    $receiver = GUICtrlRead($recipientsenter)

                    ; start added code

                    $aEmail = stringsplit($receiver,';')

                    for $1 = 1 to $aEmail[0]
                        if stringregexp($aEmail[$1],'^[\_]*([a-z0-9]+(\.|\_*)?)+@([a-z][a-z0-9\-]+(\.|\-*\.))+[a-z]{2,6}$',0) = 1 then
                            CreateMailItem()
                        Else
                            guictrlsetdata($recipientsenter,$aEmail[$1] & ' in error - not sent')
                        EndIf
                    next

                    ; end added code

                EndIf
        EndSelect
    Until $msg = $GUI_EVENT_CLOSE
    GUIDelete()
    _Exit()

EndFunc   ;==>mainlobby

The regexp was found using GOOGLE search. You don't really need to understand it to use it (although better if you do, obviously).

kylomas

[Xandy]

kylomas example reworked slightly to run without modification.

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
mainlobby()
Func mainlobby()
    Global $msg, $receiver
    Local $sendemilbutton, $recipientsread, $recipientsenter, $aEmail
    $toolname= "abc"
    $width= 320
    $height= 200
    GUICreate($toolname, $width, $height, 500, 250, default, $WS_EX_ACCEPTFILES) ; will create a dialog box that when displayed is centered
    GUISetBkColor(0x6666FF)
    $recipientsenter = GUICtrlCreateInput("", 10, 5, 250, 20)
    $sendemilbutton = GUICtrlCreateButton("Send Email", 230, 128, 70, 25, -1, 0x00000001)

    GUISetState(@SW_SHOW)

    Do
        $msg = GUIGetMsg()
        Select
            Case $msg = $sendemilbutton
                If GUICtrlRead($recipientsenter) = "" Then
                    MsgBox(16, "Email Not Input", "Cannot Find Any Email")
                Else
                    MsgBox(0, "Email Input", GUICtrlRead($recipientsenter))
                    $receiver = GUICtrlRead($recipientsenter)

                    ; start added code

                    $aEmail = stringsplit($receiver,';')

                    for $1 = 1 to $aEmail[0]
                        if stringregexp($aEmail[$1],'^[\_]*([a-z0-9]+(\.|\_*)?)+@([a-z][a-z0-9\-]+(\.|\-*\.))+[a-z]{2,6}$',0) = 1 then
                            ;CreateMailItem()
                        Else
                            guictrlsetdata($recipientsenter,$aEmail[$1] & ' in error - not sent')
                        EndIf
                    next

                    ; end added code

                EndIf
        EndSelect
    Until $msg = $GUI_EVENT_CLOSE
    GUIDelete()
    ;_Exit()
EndFunc   ;==>mainlobby

[dannydy]

Many Thanks both of you(kylomas and Xandy). Its working fine, however if i entered one email address, the program threw me an error on that. its only worked on multiple email addresses. i'm working on it right now, make some modification will handle it. Really appreciate that save me a lot of time:)

[dannydy]

i found the issue, my company address has this hyphen "-". So if i enter any email address with hypen(i.e danny-dy@hotmail.com), it will throw me an error. How to i modify the coding to handle hyphen. i did several trial and error, but i couldn't get it right.

This is the expression for handling underscore

stringregexp($aEmail[$1],'^[\_]*([a-z0-9]+(\.|\_*)?)+@([a-z][a-z0-9\-]+(\.|\-*\.))+[a-z]{2,6}$',0)

This is the expression for handling hyphen

stringregexp($aEmail[$1],'^[\-]*([a-z0-9]+(\.|\-*)?)+@([a-z][a-z0-9\-]+(\.|\-*\.))+[a-z]{2,6}$',0)

How do i make them into one statement, please?

[Xandy]

Sorry I don't know stringregexp() formatting well enough (at all really) to try to write one without getting very frustrated.

I would do something like use stringinstr() to find a '@', make sure it was not the first character. Is there always a '.' after the '@'? I don't know.

Doing it this way would not be that many lines, but it would not be one line. You could smash it into a function though.

I could write it pretty easy, would you like me to do it?

[dannydy]

Xandy, with luck i managed to do it.

Here's the code

stringregexp($aEmail[$1],'^[\_|[color=#ff0000][b]\-[/b][/color]]*([a-z0-9]+(\.|\_|[color=#ff0000][b]\-[/b][/color]*)?)+@([a-z][a-z0-9\-]+(\.|\-*\.))+[a-z]{2,6}$',0)

Basically i added - in the statement(Highlighted in red).

Many Thanks for taken a loop into it.

[PhoenixXL]

you can check the syntax of an Email.

The Regex would match most of it, excluding the special chars, U+007F above chars IP address domain name and comments.

That's the general syntax many email providers allow only a few chars other than alphanum.

Use a Case-Insensitivity switch(?i), for matching upper-case chars.

Edit: I tried to simplify the regex

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
mainlobby()

Func mainlobby()
Global $msg, $receiver
Local $sendemilbutton, $recipientsread, $recipientsenter, $aEmail
$width = 320
$height = 200
GUICreate('', 320, 200, 500, 250)
$recipientsenter = GUICtrlCreateInput("", 10, 5, 250, 20)
$sendemilbutton = GUICtrlCreateButton("Send Email", 230, 128, 70, 25, 1)
GUISetState()

Do
$msg = GUIGetMsg()
Select
Case $msg = $sendemilbutton
If GUICtrlRead($recipientsenter) = "" Then
MsgBox(16, "Email Not Input", "Cannot Find Any Email")
Else
; start added code
$aEmail = StringSplit(GUICtrlRead($recipientsenter), ';')
$localpart = "[[:alnum:]!#$%&'*+-/=?^_`{|}~.]+"
$domainname = "[[:alnum:].-]+\.[[:alnum:]]+"

For $1 = 1 To $aEmail[0]
If StringRegExp($aEmail[$1], '(?i)^(' & $localpart & ')@(' & $domainname & ')$', 0) Then
ConsoleWrite("Email_" & $1 & " is valid" & @CRLF)
Else
MsgBox(0, "Error", "Email " & $1 & " is not valid")
EndIf
Next

; end added code

EndIf
EndSelect
Until $msg = $GUI_EVENT_CLOSE
GUIDelete()
EndFunc   ;==>mainlobby

The limitations are still the same

Regards

Edited April 23, 2013 by PhoenixXL

[guinness]

I'm sure there is something on RegExLib.

[water]

Very helpful

RegExLib is a website. Take this as a starter.

[jchd]

What makes an email address "valid" is very complex in practice. Already at the email client level, what is considered valid is variable based on actual client, setup and network context. Then relays have to adhere to the same validity set of rules which is hardly the case. Finally the recipient host also has to consider valid the local part the same way as you did.

This is one of the most complex routine task in IT and I don't believe it can be done unconditionnally from a blind end. Even if the practice is doubtful (due to overload of the servers) I regard asking SMTP the most reliable approach (or the less prone to failure). Of course that means you have access to a (the!) SMTP server on the machine the validation is running on.

I don't know of any online service working correctly.

[water]

If the user runs Outlook you could use my OutlookEX UDF to validate the mail address.

Edited April 23, 2013 by water

[jchd]

Yeah or a hidden telnet (more ubiquitous) going thru until answer to RCPT TO: command.

[dannydy]

Guys, Many Thanks for the sharing. I've learnt much.

[water]

[mLipok]

On 4/23/2013 at 9:16 AM, PhoenixXL said:

you can check the syntax of an Email.

The Regex would match most of it, excluding the special chars, U+007F above chars IP address domain name and comments.

That's the general syntax many email providers allow only a few chars other than alphanum.

Use a Case-Insensitivity switch(?i), for matching upper-case chars.

 

Edit: I tried to simplify the regex

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
mainlobby()

Func mainlobby()
Global $msg, $receiver
Local $sendemilbutton, $recipientsread, $recipientsenter, $aEmail
$width = 320
$height = 200
GUICreate('', 320, 200, 500, 250)
$recipientsenter = GUICtrlCreateInput("", 10, 5, 250, 20)
$sendemilbutton = GUICtrlCreateButton("Send Email", 230, 128, 70, 25, 1)
GUISetState()

Do
$msg = GUIGetMsg()
Select
Case $msg = $sendemilbutton
If GUICtrlRead($recipientsenter) = "" Then
MsgBox(16, "Email Not Input", "Cannot Find Any Email")
Else
; start added code
$aEmail = StringSplit(GUICtrlRead($recipientsenter), ';')
$localpart = "[[:alnum:]!#$%&'*+-/=?^_`{|}~.]+"
$domainname = "[[:alnum:].-]+\.[[:alnum:]]+"

For $1 = 1 To $aEmail[0]
If StringRegExp($aEmail[$1], '(?i)^(' & $localpart & ')@(' & $domainname & ')$', 0) Then
ConsoleWrite("Email_" & $1 & " is valid" & @CRLF)
Else
MsgBox(0, "Error", "Email " & $1 & " is not valid")
EndIf
Next

; end added code

EndIf
EndSelect
Until $msg = $GUI_EVENT_CLOSE
GUIDelete()
EndFunc   ;==>mainlobby

The limitations are still the same

 

Regards

 

I know old thread.

Just needed to us this snippet

so wanted to share my refactored version:

expandcollapse popup

;~ https://www.autoitscript.com/forum/topic/150225-validate-if-user-entering-the-right-email-address-format/#findComment-1072558

#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>
#include <StringConstants.au3>
#include <WindowsConstants.au3>

mainlobby()

Func mainlobby()
    GUICreate('', 320, 200, 500, 250)
    Local $recipientsenter = GUICtrlCreateInput("", 10, 5, 250, 20)
    Local $sendemilbutton = GUICtrlCreateButton("Send Email", 230, 128, 70, 25, 1)
    GUISetState()

    Local $msg
    Do
        $msg = GUIGetMsg()
        Select
            Case $msg = $sendemilbutton
                Local $sEMail = GUICtrlRead($recipientsenter)
                If $sEMail = "" Then
                    MsgBox(16, "Email Not Input", "Cannot Find Any Email")
                Else
                    MsgBox($MB_TOPMOST, "TEST #" & @ScriptLineNumber, "IsValidEmailAdress = " & _IsValidEmailAdress($sEMail))
                EndIf
        EndSelect
    Until $msg = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>mainlobby

Func _IsValidEmailAdress($sEMail)
    Local $aEmail = StringSplit($sEMail, ';')
    Local $localpart = "[[:alnum:]!#$%&'*+-/=?^_`{|}~.]+"
    Local $domainname = "[[:alnum:].-]+\.[[:alnum:]]+"

    Local $i_CountValid = 0
    For $IDX = 1 To $aEmail[0]
        If StringRegExp($aEmail[$IDX], '(?i)^(' & $localpart & ')@(' & $domainname & ')$', $STR_REGEXPMATCH) Then
            $i_CountValid += 1
        EndIf
    Next
    Return ($i_CountValid = $aEmail[0])
EndFunc   ;==>_IsValidEmailAdress

 

Edited 10 hours ago by mLipok